@echo off
title Install Office _ Soft98.iR
fltmc >nul 2>&1 || powershell -NoProfile -Command "Start-Process '%~f0' -Verb RunAs" >nul 2>&1 && exit /b
setlocal EnableDelayedExpansion
mode con: cols=90 lines=30
cls
echo.&@echo          лллллл   ллллллл  лллллллл лллллллл  ллллллл   ллллллл      лллл лллллллл  &@echo         лл    лл лл     лл лл          лл    лл     лл лл     лл      лл  лл     лл &@echo         лл       лл     лл лл          лл    лл     лл лл     лл      лл  лл     лл &@echo          лллллл  лл     лл лллллл      лл     лллллллл  ллллллл       лл  лллллллл  &@echo               лл лл     лл лл          лл           лл лл     лл      лл  лл   лл   &@echo         лл    лл лл     лл лл          лл    лл     лл лл     лл ллл  лл  лл    лл  &@echo          лллллл   ллллллл  лл          лл     ллллллл   ллллллл  ллл лллл лл     лл  &echo.&@echo         лллллллллллллллллллллллллллллллллллллллллллллллллллллллллллллллллллллллллллл&echo.&echo.
echo.
echo ===================================================
echo     Checking for existing Office installations
echo ===================================================
echo.

set "FOUND=0"

reg query "HKLM\SOFTWARE\Microsoft\Office\ClickToRun\Configuration" /v ProductReleaseIds >nul 2>&1
if !errorlevel! equ 0 (
    set "FOUND=1"
    powershell -Command "function Show-Message($t,$f,$b){Write-Host $t -ForegroundColor $f -BackgroundColor $b}; Show-Message '   Office Detected:   ' White Red"
 
    echo.
    for /f "tokens=2,*" %%A in ('reg query "HKLM\SOFTWARE\Microsoft\Office\ClickToRun\Configuration" /v ProductReleaseIds 2^>nul ^| find "ProductReleaseIds"') do (
        for %%i in (%%B) do (
            set "id=%%i"
            set "name=!id!"
            if /i "!id!"=="O365ProPlusRetail"   set "name=Microsoft 365 / Office 365"
            if /i "!id!"=="ProPlus2024Retail"   set "name=Office 2024 Professional Plus"
            if /i "!id!"=="ProPlus2021Retail"   set "name=Office 2021 Professional Plus"
            if /i "!id!"=="ProPlus2019Retail"   set "name=Office 2019 Professional Plus"
            if not defined done_!id! (
                echo      - !name!
                set "done_!id!=1"
            )
        )
    )
    echo.
)

if exist "C:\Program Files\Microsoft Office\root\Office16"      set "FOUND=1"
if exist "C:\Program Files (x86)\Microsoft Office\root\Office16" set "FOUND=1"

echo ==================================================
if "%FOUND%"=="1" (
    echo.
    choice /c YN /n /m "     Uninstall all Office now? (Y/N): "
    if errorlevel 2 (
        echo.
        echo     Skipping uninstall. Proceeding to installation...
        timeout /t 1 >nul
        goto :SelectVersion
    )
    if errorlevel 1 (
        if exist "%~dp0Uninstall.cmd" (
            start "Office Uninstaller" /min cmd /c ""%~dp0Uninstall.cmd""
            echo.
            echo     Please wait until uninstall completes, then run this installer again.
            exit /b
        ) else (
            echo     ERROR: Uninstall.cmd not found
            pause
            exit /b
        )
    )
)

:SelectVersion
cls
echo.&@echo          лллллл   ллллллл  лллллллл лллллллл  ллллллл   ллллллл      лллл лллллллл  &@echo         лл    лл лл     лл лл          лл    лл     лл лл     лл      лл  лл     лл &@echo         лл       лл     лл лл          лл    лл     лл лл     лл      лл  лл     лл &@echo          лллллл  лл     лл лллллл      лл     лллллллл  ллллллл       лл  лллллллл  &@echo               лл лл     лл лл          лл           лл лл     лл      лл  лл   лл   &@echo         лл    лл лл     лл лл          лл    лл     лл лл     лл ллл  лл  лл    лл  &@echo          лллллл   ллллллл  лл          лл     ллллллл   ллллллл  ллл лллл лл     лл  &echo.&@echo         лллллллллллллллллллллллллллллллллллллллллллллллллллллллллллллллллллллллллллл&echo.&echo.
echo.
echo ===================================================
echo                SELECT OFFICE VERSION
echo ===================================================
echo.
echo       1. Microsoft 365
echo       2. Office 2024
echo       3. Office 2021
echo       4. Office 2019
echo.
choice /c 1234 /n /m "     Select version [1-4]: "
set "ver=%errorlevel%"

if %ver%==1 set "PID=O365ProPlusRetail" & set "VIS=VisioPro2024Retail" & set "PR=ProjectPro2024Retail" & set "name=Microsoft 365"
if %ver%==2 set "PID=ProPlus2024Retail" & set "VIS=VisioPro2024Retail" & set "PR=ProjectPro2024Retail" & set "name=Office 2024"
if %ver%==3 set "PID=ProPlus2021Retail" & set "VIS=VisioPro2021Retail" & set "PR=ProjectPro2021Retail" & set "name=Office 2021"
if %ver%==4 set "PID=ProPlus2019Retail" & set "VIS=VisioPro2019Retail" & set "PR=ProjectPro2019Retail" & set "name=Office 2019"

:SelectApps
powershell -Command "$Host.UI.RawUI.BufferSize = New-Object System.Management.Automation.Host.Size(90, 50)"
cls
echo.
echo ===================================================
echo          %name% - Select Applications
echo ===================================================
echo.
echo    0.  Install ALL Office apps (1-9)
echo.
echo    1.  Word
echo    2.  Excel
echo    3.  PowerPoint
echo    4.  Outlook
echo    5.  OneNote
echo    6.  Access
echo    7.  Publisher
echo    8.  OneDrive
echo    9.  Lync
echo.
echo   10.  Visio
echo   11.  Project
echo.
echo ===================================================
echo (If you need Word + Excel, type the numbers 1 2 with a space)
echo.
set "input="
set /p "input=Enter numbers by space (1 2 3 4 5 6 7 8 9 10 11 OR 0): "
if "!input!"=="" goto SelectApps
if /i "!input!"=="0" set "input=1 2 3 4 5 6 7 8 9"

for %%a in (!input!) do (
    if %%a lss 0 (
        echo.
        powershell -Command "function Show-Message($t,$f,$b){Write-Host $t -ForegroundColor $f -BackgroundColor $b}; Show-Message '   ERROR:   ' White Red"
        echo     Invalid selection "%%a". Please enter numbers between 0 and 11.
        timeout /t 4 >nul
        goto SelectApps
    )
    if %%a gtr 11 (
        echo.
        powershell -Command "function Show-Message($t,$f,$b){Write-Host $t -ForegroundColor $f -BackgroundColor $b}; Show-Message '   ERROR:   ' White Red"
        echo     Invalid selection "%%a". Please enter numbers between 0 and 11.
        timeout /t 4 >nul
        goto SelectApps
    )
)

set "installWord=0"
set "installExcel=0"
set "installPowerPoint=0"
set "installOutlook=0"
set "installOneNote=0"
set "installAccess=0"
set "installPublisher=0"
set "installOneDrive=0"
set "installLync=0"
set "installVisio=0"
set "installProject=0"

for %%a in (!input!) do (
    if %%a==1 set installWord=1
    if %%a==2 set installExcel=1
    if %%a==3 set installPowerPoint=1
    if %%a==4 set installOutlook=1
    if %%a==5 set installOneNote=1
    if %%a==6 set installAccess=1
    if %%a==7 set installPublisher=1
    if %%a==8 set installOneDrive=1
    if %%a==9 set installLync=1
    if %%a==10 set installVisio=1
    if %%a==11 set installProject=1
)

echo.
echo   Selected applications:
if %installWord%==1 echo      - Word
if %installExcel%==1 echo      - Excel
if %installPowerPoint%==1 echo      - PowerPoint
if %installOutlook%==1 echo      - Outlook
if %installOneNote%==1 echo      - OneNote
if %installAccess%==1 echo      - Access
if %installPublisher%==1 echo      - Publisher
if %installOneDrive%==1 echo      - OneDrive
if %installLync%==1 echo      - Lync
if %installVisio%==1 echo      - Visio
if %installProject%==1 echo      - Project
echo.

(
echo ^<?xml version="1.0" encoding="utf-8"?^>
echo ^<Configuration^>
echo   ^<Add OfficeClientEdition="64" Channel="Current"^>
) > "%TEMP%\ocfg.xml"

set "installMain=0"
for %%a in (!input!) do if %%a LEQ 10 set "installMain=1"

if !installMain! == 1 (
    echo     ^<Product ID="%PID%"^> >> "%TEMP%\ocfg.xml"
    echo       ^<Language ID="en-us" /^> >> "%TEMP%\ocfg.xml"

    if %installWord%==0 echo       ^<ExcludeApp ID="Word" /^> >> "%TEMP%\ocfg.xml"
    if %installExcel%==0 echo       ^<ExcludeApp ID="Excel" /^> >> "%TEMP%\ocfg.xml"
    if %installPowerPoint%==0 echo       ^<ExcludeApp ID="PowerPoint" /^> >> "%TEMP%\ocfg.xml"
    if %installOutlook%==0 echo       ^<ExcludeApp ID="Outlook" /^> >> "%TEMP%\ocfg.xml"
    if %installOneNote%==0 echo       ^<ExcludeApp ID="OneNote" /^> >> "%TEMP%\ocfg.xml"
    if %installAccess%==0 echo       ^<ExcludeApp ID="Access" /^> >> "%TEMP%\ocfg.xml"
    if %installPublisher%==0 echo       ^<ExcludeApp ID="Publisher" /^> >> "%TEMP%\ocfg.xml"
    if %installOneDrive%==0 echo       ^<ExcludeApp ID="Groove" /^> >> "%TEMP%\ocfg.xml"	
    if %installOneDrive%==0 echo       ^<ExcludeApp ID="OneDrive" /^> >> "%TEMP%\ocfg.xml"
    if %installLync%==0 echo       ^<ExcludeApp ID="Lync" /^> >> "%TEMP%\ocfg.xml"

    echo     ^</Product^> >> "%TEMP%\ocfg.xml"
)

if %installVisio%==1 (
    echo     ^<Product ID="%VIS%"^> >> "%TEMP%\ocfg.xml"
    echo       ^<Language ID="en-us" /^> >> "%TEMP%\ocfg.xml"
    echo       ^<ExcludeApp ID="Groove" /^> >> "%TEMP%\ocfg.xml"		
    echo       ^<ExcludeApp ID="OneDrive" /^> >> "%TEMP%\ocfg.xml"		
    echo     ^</Product^> >> "%TEMP%\ocfg.xml"
)

if %installProject%==1 (
    echo     ^<Product ID="%PR%"^> >> "%TEMP%\ocfg.xml"
    echo       ^<Language ID="en-us" /^> >> "%TEMP%\ocfg.xml"
    echo       ^<ExcludeApp ID="Groove" /^> >> "%TEMP%\ocfg.xml"		
    echo       ^<ExcludeApp ID="OneDrive" /^> >> "%TEMP%\ocfg.xml"	
    echo     ^</Product^> >> "%TEMP%\ocfg.xml"
)

(
echo   ^</Add^>
echo   ^<Property Name="SharedComputerLicensing" Value="0" /^>
echo   ^<Property Name="FORCEAPPSHUTDOWN" Value="FALSE" /^>
echo   ^<Property Name="DeviceBasedLicensing" Value="0" /^>
echo   ^<Property Name="SCLCacheOverride" Value="0" /^>
echo   ^<Property Name="AUTOACTIVATE" Value="0" /^>
echo   ^<Property Name="Groove" Value="FALSE" /^>
echo   ^<Property Name="OneDrive" Value="FALSE" /^>
echo   ^<Display Level="Full" AcceptEULA="TRUE" /^>
echo   ^<Updates Enabled="TRUE" /^>
echo   ^<RemoveMSI /^>
echo ^</Configuration^>
) >> "%TEMP%\ocfg.xml"


set "ODTPath=%~dp0ODT.exe"
if not exist "%ODTPath%" (
    echo     ERROR: ODT.exe not found in %~dp0
    pause
    exit /b 1
)

echo   Installing %name% ...
"%ODTPath%" /configure "%TEMP%\ocfg.xml"

if %errorlevel%==0 (
    echo.
    echo ===================================================
    echo         %name% installed successfully!
	echo.
	echo                      Soft98.iR
    echo ===================================================
) else (
    echo.
    echo     Installation failed ^(Error code: %errorlevel%^)
)

del "%TEMP%\ocfg.xml" >nul 2>&1
echo.
echo Press any key to Exit . . .
pause >nul
exit /b